flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

{
  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:nix-ocaml/nix-overlays";
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = nixpkgs.legacyPackages.${system}.appendOverlays [
        (self: super: {
          ocamlPackages =
            super.ocaml-ng.ocamlPackages_5_1.overrideScope'
            (oself: osuper: {
              pg_query = osuper.pg_query.overrideAttrs (prev: {
                propagatedBuildInputs =
                  prev.propagatedBuildInputs
                  ++ [osuper.cmdliner];
              });
            });
        })
      ];

      combattant = pkgs.ocamlPackages.buildDunePackage {
        pname = "combattant";
        version = "0.0.1";
        src = ./.;
        buildInputs = with pkgs.ocamlPackages; [
          ppx_rapper
          ppx_rapper_eio
          yojson
          eio_main
          piaf
          routes
          caqti-dynload
          caqti-driver-postgresql
          caqti-driver-sqlite3
          pkgs.sqlite
          ppx_expect

          logs
        ];
      };
    in {
      devShells.default = pkgs.mkShell rec {
        nativeBuildInputs = with pkgs.ocamlPackages; [
          dune_3
          findlib
          ocaml
          ocaml-lsp
          ocamlformat
          pkgs.openjdk17
          pkgs.sqlite
        ];

        buildInputs =
          combattant.buildInputs
          ++ (with pkgs.ocamlPackages; [utop]);
      };

      packages.default = combattant;
    });
}